Re: Reply-To: emacs-w3m@namazu.org, non-subscriber

[TSUCHIYA Masatoshi <tsuchiya@xxxxxxxxxx>]

>> On Fri, 09 Dec 2005 20:07:54 +0900
>> 「山」== yamaoka@xxxxxxx (Katsumi Yamaoka) said as follows:

山> この問題の最良の解は、メーリングリストのサーバーが、常にすべての
山> 宛先を Reply-To ヘッダーに含めてしまうことではないでしょうか?

えーっと，そのように設定すると，例えば山岡さんの投稿にも

    Reply-To: emacs-w3m＠namazu.org, yamaoka＠jpl.org

というへッダがつくことになって，その投稿に不用意に返信すると，

    To: emacs-w3m＠namazu.org, yamaoka＠jpl.org

となり，山岡さんのところには同じメールが2通届くことになってしまうので
はないかと思うのですが…．

私は，メーリングリストと通常のアドレスに同時に返信する場合には，
Mail-Followup-To: へッダをつけるようにして対処しています．

(if (fboundp 'std11-extract-addresses-components)
    (defun my-mail-parse-addresses (val)
      (mapcar (lambda (c) (nth 1 c))
	      (std11-extract-addresses-components val)))
  (defun my-mail-parse-addresses (val)
    (mapcar 'car (mail-header-parse-addresses val))))

(defun my-message-recipients ()
  "Return recipients of this current message."
  (nconc (my-mail-parse-addresses (message-fetch-field "To"))
	 (my-mail-parse-addresses (message-fetch-field "Cc"))))

(defun my-message-insert-mail-followup-to ()
  (save-excursion
    (save-restriction
      (message-narrow-to-headers-or-head)
      (unless (message-fetch-field "Mail-Followup-To")
	(let (lists others)
	  (dolist (x (my-message-recipients))
	    (if (assoc x my-subscribed-mailing-lists)
		(push x lists)
	      (push x others)))
	  (and lists  ; addresses for mailing lists
	       others ; addresses for others
	       (message-add-header
		(format "Mail-Followup-To: %s" (car lists)))))))))

(defvar my-subscribed-mailing-lists (list "emacs-w3m@xxxxxxxxxx"))

(add-hook 'message-header-setup-hook 'my-message-insert-mail-followup-to)

-- 
土屋 雅稔 ( TSUCHIYA Masatoshi )